// [RCD] 
// 起動/停止 :  V/ F
// 出力大/小 :  V/ D
// 上昇/下降 :  S/ X
// 左右回頭  :  Z/ C
// 前進/後退 : ↑/↓
// 左右旋回  : ←/→
// 射撃　　　:  A
// 出力43000から定常運転・射撃が可能（目安）
Val
{
	ARM(default=0, max=30, step=5, disp=0)
	C1(default=0, min=-6, max=6, step=6, disp=0)
	C2(default=0, min=-6, max=6, step=6, disp=0)
	CC(default=-90, min=-120, max=-60, step=6, disp=0)
	CR(default=0, min=-5, max=5, step=5, disp=0)
	CT(default=0, max=1, step=1, disp=0)
	DT(default=0, disp=0)
	ENGINE(default=0, max=55000)
	K1(default=0, max=1, disp=0)
	K2(default=0, max=1, disp=0)
	R11(default=18, min=-6, max=42, step=6, disp=0)
	R12(default=18, min=-6, max=42, step=6, disp=0)
	R21(default=18, min=-6, max=42, step=6, disp=0)
	R22(default=18, min=-6, max=42, step=6, disp=0)
	ROLL(default=0, min=-10000, max=10000, step=25)
	TRIG1(default=0, max=50000, step=50000, disp=0)
	TRIG2(default=0, max=50000, step=50000, disp=0)
	UD(default=0, min=-20, max=15, step=7, disp=0)
}
Key
{
	0:C1(step=-1)
	1:C1(step=1)
	2:C2(step=-1)
	3:C2(step=1)
	4:CR(step=1)
	5:UD(step=-3)
	6:CR(step=-1)
	7:CT(step=1)
	8:UD(step=3)
	9:ENGINE(step=-1000)
	10:ENGINE(step=1000), K1(step=1)
	12:K1(step=-1), ENGINE(step=-5000)
}
Body
{
	Core(color=COL_TEAM, user2=301) {
		S:Frame(angle=CC, damper=0.3) {
			S:Wheel(angle=-90, power=ROLL, option=1, color=#000000, effect=1, name=main) {
				S:Wheel(angle=180, power=-ENGINE) {
					N:TrimF(angle=R12, name=p1) {
						N:Chip() { }
					}
					S:TrimF(angle=R11, name=p3) {
						S:Chip() { }
					}
				}
				S:Wheel(angle=180, power=ENGINE, name=ROT1) {
					N:TrimF(angle=-R21, name=p2) {
						N:Chip() { }
					}
					S:TrimF(angle=-R22, name=p4) {
						S:Chip() { }
					}
				}
			}
		}
		W:Frame(angle=ARM) {
			N:Arm(power=TRIG2, option=50000) { }
			S:Arm(power=TRIG2, option=50000) { }
		}
		E:Frame(angle=ARM) {
			N:Arm(power=TRIG1, option=50000) { }
			S:Arm(power=TRIG1, option=50000) { }
		}
	}
}
Script
{
	CRS=-_VZ(0)
	CLS=-_VY(0)

	CEX=_ASIN(_XY(main-1))
	CEZ=_ASIN(_ZY(main-1))

	CC=-90+_TODEG(CEZ)/2*K2
	ROLL=(-60*_LY()/_DT()-0.6*CR/_DT()*_ABS(_LY())/_DT())*K1

	if K1>0 & ENGINE>43000{ARM=ARM+3 K2=K2+1}
	if K1=0{ARM=ARM-3 K2=K2-1}
	DT=DT+CT
	TRIG1=_SIN(DT/2)*CT*100000
	TRIG2=_SIN(DT/2+_PI())*CT*100000

	R11=((C2-CEX*10)*_SIN(_RY(main-1,p3))-(-C1+CEZ*10)*_COS(_RY(main-1,p3))+CLS*2)*K1+UD+18
	R22=((C2-CEX*10)*_SIN(_RY(main-1,p4))-(-C1+CEZ*10)*_COS(_RY(main-1,p4))+CLS*2)*K1+UD+18
	R12=((-C1+CEZ*10)*_COS(_RY(main-1,p1))-(C2-CEX*10)*_SIN(_RY(main-1,p1))+CLS*2)*K1+UD+18
	R21=((-C1+CEZ*10)*_COS(_RY(main-1,p2))-(C2-CEX*10)*_SIN(_RY(main-1,p2))+CLS*2)*K1+UD+18

	PRINT 1,"Engine_power   : ",ENGINE/590," %"
	PRINT 2,"Cruising_speed : ",CRS* 3.6," km/h"
	PRINT 3,"Climbing_speed : ",CLS*-3.6," km/h"
	PRINT 5,"50-_CHIPS()    : ",50-_CHIPS()," pt"
	PRINT 6,"-60*_LY()/_DT()*K1: ",-60*_LY()/_DT()*K1," pt"
}